qmake高級(jí)概念

迄今為止，我們見(jiàn)到的qmake項(xiàng)目文件都非常簡(jiǎn)單，僅僅是一些name = value和name += value的列表行。qmake提供了很多更強(qiáng)大的功能，比如你可以使用一個(gè)簡(jiǎn)單的項(xiàng)目文件來(lái)為多個(gè)平臺(tái)生成makefile。

操作符

到目前為止，你已經(jīng)看到在項(xiàng)目文件中使用的=操作符和+=操作符。這里能夠提供更多的可供使用的操作符，但是其中的一些需要謹(jǐn)慎地使用，因?yàn)樗鼈円苍S會(huì)比你期待的改變的更多。

“=”操作符

這個(gè)操作符簡(jiǎn)單分配一個(gè)值給一個(gè)變量。使用方法如下：

    TARGET = myapp

這將會(huì)設(shè)置TARGET變量為myapp。這將會(huì)刪除原來(lái)對(duì)TARGET的任何設(shè)置。

“+=”操作符

這個(gè)操作符將會(huì)向一個(gè)變量的值的列表中添加一個(gè)值。使用方法如下：

    DEFINES += QT_DLL

這將會(huì)把QT_DLL添加到被放到makefile中的預(yù)處理定義的列表中。

“-=”操作符

這個(gè)操作符將會(huì)從一個(gè)變量的值的列表中移去一個(gè)值。使用方法如下：

    DEFINES -= QT_DLL

這將會(huì)從被放到makefile中的預(yù)處理定義的列表中移去QT_DLL。

“*=”操作符

這個(gè)操作符僅僅在一個(gè)值不存在于一個(gè)變量的值的列表中的時(shí)候，把它添加進(jìn)去。使用方法如下：

    DEFINES *= QT_DLL

只用在QT_DLL沒(méi)有被定義在預(yù)處理定義的列表中時(shí)，它才會(huì)被添加進(jìn)去。

“~=”操作符

這個(gè)操作符將會(huì)替換任何與指定的值的正則表達(dá)式匹配的任何值。使用方法如下：

    DEFINES ~= s/QT_[DT].+/QT

這將會(huì)用QT來(lái)替代任何以QT_D或QT_T開(kāi)頭的變量中的QT_D或QT_T。

作用域

作用域和“if”語(yǔ)句很相似，如果某個(gè)條件為真，作用域中的設(shè)置就會(huì)被處理。作用域使用方法如下：

    win32 {
        DEFINES += QT_DLL
    }

上面的代碼的作用是，如果在Windows平臺(tái)上使用qmake，QT_DLL定義就會(huì)被添加到makefile中。如果在Windows平臺(tái)以外的平臺(tái)上使用qmake，這個(gè)定義就會(huì)被忽略。你也可以使用qmake執(zhí)行一個(gè)單行的條件/任務(wù)，就像這樣：

    win32:DEFINES += QT_DLL

比如，假設(shè)我們想在除了Windows平臺(tái)意外的所有平臺(tái)處理些什么。我們想這樣使用作用域來(lái)達(dá)到這種否定效果：

    !win32 {
        DEFINES += QT_DLL
    }

CONFIG行中的任何條目也都是一個(gè)作用域。比如，你這樣寫：

    CONFIG += warn_on

你將會(huì)得到一個(gè)稱作“warn_on”的作用域。這樣將會(huì)使在不丟失特定條件下可能所需的所有自定義設(shè)置的條件下，很容易地修改項(xiàng)目中的配置。因?yàn)槟憧赡馨涯阕约旱闹捣诺紺ONFIG行中，這將會(huì)為你的makefile而提供給你一個(gè)非常強(qiáng)大的配置工具。比如：

    CONFIG += qt warn_on debug
    debug {
        TARGET = myappdebug
    }
    release {
        TARGET = myapp
    }

在上面的代碼中，兩個(gè)作用域被創(chuàng)建，它們依賴于CONFIG行中設(shè)置的是什么。在這個(gè)例子中，debug在CONFIG行中，所以TARGET變量被設(shè)置為myappdebug。如果release在CONFIG行中，那么TARGET變量將會(huì)被設(shè)置為myapp。

當(dāng)然也可以在處理一些設(shè)置之前檢查兩個(gè)事物。例如，如果你想檢查平臺(tái)是否是Windows并且線程設(shè)置是否被設(shè)定，你可以這樣寫：

    win32 {
        thread {
            DEFINES += QT_THREAD_SUPPORT
        }
    }

為了避免寫出許多嵌套作用域，你可以這樣使用冒號(hào)來(lái)嵌套作用域：

    win32:thread {
        DEFINES += QT_THREAD_SUPPORT
    }

一旦一個(gè)測(cè)試被執(zhí)行，你也許也要做else/elseif操作。這種情況下，你可以很容易地寫出復(fù)雜的測(cè)試。這需要使用特殊的“else”作用域，它可以和其它作用域進(jìn)行組合（也可以向上面一樣使用冒號(hào)），比如：

    win32:thread {
        DEFINES += QT_THREAD_SUPPORT
    } else:debug {
        DEFINES += QT_NOTHREAD_DEBUG
    } else {
        warning("Unknown configuration")
    }

變量

到目前為止我們遇到的變量都是系統(tǒng)變量，比如DEFINES、SOURCES和HEADERS。你也可以為你自己創(chuàng)建自己的變量，這樣你就可以在作用域中使用它們了。創(chuàng)建自己的變量很容易，只要命名它并且分配一些東西給它。比如：

    MY_VARIABLE = value

現(xiàn)在你對(duì)你自己的變量做什么是沒(méi)有限制的，同樣地，qmake將會(huì)忽略它們，除非需要在一個(gè)作用域中考慮它們。

你也可以通過(guò)在其它任何一個(gè)變量的變量名前加$$來(lái)把這個(gè)變量的值分配給當(dāng)前的變量。例如：

    MY_DEFINES = $$DEFINES

現(xiàn)在MY_DEFINES變量包含了項(xiàng)目文件在這點(diǎn)時(shí)DEFINES變量的值。這也和下面的語(yǔ)句一樣：

 
    MY_DEFINES = $${DEFINES}

第二種方法允許你把一個(gè)變量和其它變量連接起來(lái)，而不用使用空格。qmake將允許一個(gè)變量包含任何東西（包括$(VALUE)，可以直接在makefile中直接放置，并且允許它適當(dāng)?shù)財(cái)U(kuò)張，通常是一個(gè)環(huán)境變量）。無(wú)論如何，如果你需要立即設(shè)置一個(gè)環(huán)境變量，然后你就可以使用$$()方法。比如：

    MY_DEFINES = $$(ENV_DEFINES)

這將會(huì)設(shè)置MY_DEFINES為環(huán)境變量ENV_DEFINES傳遞給.pro文件地值。另外你可以在替換的變量里調(diào)用內(nèi)置函數(shù)。這些函數(shù)（不會(huì)和下一節(jié)中列舉的測(cè)試函數(shù)混淆）列出如下：

join( variablename, glue, before, after )

這將會(huì)在variablename的各個(gè)值中間加入glue。如果這個(gè)變量的值為非空，那么就會(huì)在值的前面加一個(gè)前綴before和一個(gè)后綴after。只有variablename是必須的字段，其它默認(rèn)情況下為空串。如果你需要在glue、before或者after中使用空格的話，你必須提供它們。

member( variablename, position )

這將會(huì)放置variablename的列表中的position位置的值。如果variablename不夠長(zhǎng)，這將會(huì)返回一個(gè)空串。variablename是唯一必須的字段，如果沒(méi)有指定位置，則默認(rèn)為列表中的第一個(gè)值。

find( variablename, substr )

這將會(huì)放置variablename中所有匹配substr的值。substr也可以是正則表達(dá)式，而因此將被匹配。

    MY_VAR = one two three four
    MY_VAR2 = $$join(MY_VAR, " -L", -L) -Lfive
    MY_VAR3 = $$member(MY_VAR, 2) $$find(MY_VAR, t.*)

MY_VAR2將會(huì)包含“-Lone -Ltwo -Lthree -Lfour -Lfive”，并且MYVAR3將會(huì)包含“three two three”。

system( program_and_args )

這將會(huì)返回程序執(zhí)行在標(biāo)準(zhǔn)輸出/標(biāo)準(zhǔn)錯(cuò)誤輸出的內(nèi)容，并且正像平時(shí)所期待地分析它。比如你可以使用這個(gè)來(lái)詢問(wèn)有關(guān)平臺(tái)的信息。

    UNAME = $$system(uname -s)
    contains( UNAME, [lL]inux ):message( This looks like Linux ($$UNAME) to me )

測(cè)試函數(shù)

qmake提供了可以簡(jiǎn)單執(zhí)行，但強(qiáng)大測(cè)試的內(nèi)置函數(shù)。這些測(cè)試也可以用在作用域中（就像上面一樣），在一些情況下，忽略它的測(cè)試值，它自己使用測(cè)試函數(shù)是很有用的。

contains( variablename, value )

如果value存在于一個(gè)被叫做variablename的變量的值的列表中，那么這個(gè)作用域中的設(shè)置將會(huì)被處理。例如：

    contains( CONFIG, thread ) {
        DEFINES += QT_THREAD_SUPPORT
    }

如果thread存在于CONFIG變量的值的列表中時(shí)，那么QT_THREAD_SUPPORT將會(huì)被加入到DEFINES變量的值的列表中。

count( variablename, number )

如果number與一個(gè)被叫做variablename的變量的值的數(shù)量一致，那么這個(gè)作用域中的設(shè)置將會(huì)被處理。例如：

    count( DEFINES, 5 ) {
        CONFIG += debug
    }

error( string )

這個(gè)函數(shù)輸出所給定的字符串，然后會(huì)使qmake退出。例如：

    error( "An error has occured" )

文本“An error has occured”將會(huì)被顯示在控制臺(tái)上并且qmake將會(huì)退出。

exists( filename )

如果指定文件存在，那么這個(gè)作用域中的設(shè)置將會(huì)被處理。例如：

    exists( /local/qt/qmake/main.cpp ) {
        SOURCES += main.cpp
    }

如果/local/qt/qmake/main.cpp存在，那么main.cpp將會(huì)被添加到源文件列表中。

注意可以不用考慮平臺(tái)使用“/”作為目錄的分隔符。

include( filename )

項(xiàng)目文件在這一點(diǎn)時(shí)包含這個(gè)文件名的內(nèi)容，所以指定文件中的任何設(shè)置都將會(huì)被處理。例如：

 
    include( myotherapp.pro )

myotherapp.pro項(xiàng)目文件中的任何設(shè)置現(xiàn)在都會(huì)被處理。

isEmpty( variablename )

這和使用count( variablename, 0 )是一樣的。如果叫做variablename的變量沒(méi)有任何元素，那么這個(gè)作用域中的設(shè)置將會(huì)被處理。例如：

    isEmpty( CONFIG ) {
        CONFIG += qt warn_on debug
    }

message( string )

這個(gè)函數(shù)只是簡(jiǎn)單地在控制臺(tái)上輸出消息。

    message( "This is a message" )

文本“This is a message”被輸出到控制臺(tái)上并且對(duì)于項(xiàng)目文件的處理將會(huì)繼續(xù)進(jìn)行。

system( command )

特定指令被執(zhí)行并且如果它返回一個(gè)1的退出值，那么這個(gè)作用域中的設(shè)置將會(huì)被處理。例如：

    system( ls /bin ) {
        SOURCES += bin/main.cpp
        HEADERS += bin/main.h
    }

所以如果命令ls /bin返回1，那么bin/main.cpp將被添加到源文件列表中并且bin/main.h將被添加到頭文件列表中。

infile( filename, var, val )

如果filename文件（當(dāng)它被qmake自己解析時(shí)）包含一個(gè)值為val的變量var，那么這個(gè)函數(shù)將會(huì)返回成功。你也可以不傳遞第三個(gè)參數(shù)（val），這時(shí)函數(shù)將只測(cè)試文件中是否分配有這樣一個(gè)變量var。